# Сохраняет квест и цель, чтобы потом в конце анимации появился сам текст
$data merge storage temp {quests:{title:"$(title)"}}
$data merge storage temp {quests:{task:"$(task)"}}

# Убирает визуальное название квеста и цели, чтобы текст не висел сверху анимации
bossbar set quest.title name {"text":" ","color":"#feffff","shadow_color":[0,0,0,0],"bold":true}
bossbar set quest.task name {"text":" ","color":"#feffff","shadow_color":[0,0,0,0]}

# Расставляет боссбар по порядку, если вдруг он сломан у игрока
bossbar set quest.bg players @a
bossbar set quest.title players @a
bossbar set quest.task players @a
bossbar set quest.bg visible false
bossbar set quest.title visible false
bossbar set quest.task visible false
bossbar set quest.bg visible true
bossbar set quest.title visible true
bossbar set quest.task visible true

# Запускает анимацию
function lbdm:main/quest_ui/appear