# Не знаю зачем, но ставит какой сейчас квест в массив
data merge storage lbdm:main {quest:2}

# Перемещает монстрика за дверь
tp @e[tag=quest2_rawr_ai,limit=1,sort=nearest] 205.0 -60.0 13.0 180 0

# Забирает тег что игрок был съеден монстром
tag @e[tag=quest2_rawr_ai,limit=1,sort=nearest] remove screamer

# Возвращает интеллект монстру
data merge entity @e[tag=quest2_rawr_ai,limit=1] {NoAI:0b}

# Анимация ходьбы у монстра
execute as @e[tag=aj.quest2_rawr.root] run function animated_java:quest2_rawr/animations/walk/play

# Туман
function lbdm:quest2/fog

# Костыль
advancement revoke @a only lbdm:click/quest2/fake_door
advancement revoke @a only lbdm:click/quest2/door

# Возвращает игроку нормальную прыгучесть
execute as @a run attribute @s jump_strength base set 0.42

# Игрок возвращается и смотрит на монстра
tp @a 205.0 -60 3.0 0 2

# Ресет квеста
function lbdm:main/quest_ui/reset

# Выдаёт игроку 4 отмычки и запирает обратно двери
kill @e[type=item]
clear @a firework_star
give @a firework_star[item_model="lbdm:quest2/lockpick",item_name='{"text":"Отмычка"}',custom_data={quest2_lockpick:1b}] 4
function lbdm:quest2/door/reset
function lbdm:quest2/fake_door/reset

# Запускает триггер выключения монстра и в конце
#function lbdm:quest2/rawr_remove
#function lbdm:quest2/end

# Цель - бежать
function lbdm:main/quest_ui/init {title:"Путь длиной в 13 км",task:"Беги."}